aardio + R 语言互调函数如此简单

为了尽量追求简洁，尽量不把时间浪费在部署环境这些琐事上，aardio 将会自动检测 R 语言环境，如果没找到，就会全自动安装部署好 R 环境。

用法特简单：

import process.r;


process.r.code = /***
write("<?="这是 aardio 代码"?>",file=".data.txt");
***/

如上直接在 process.r.code 里写 R代码，可以与 aardio 代码混写，aardio 代码写在 <? ..... ?> 标记中间就可以了， aardio 的这种模板语法跟 PHP 一样，简单方便，就不过多解释了。

如果需要获取 R 的进程输出，那么上面的代码可以改写如下：

import process.r;
var out = process.r.loadcode(`
write("<?="这是 aardio 代码"?>",file=".data.txt");
readLines(".data.txt");`)

上面包含 R 代码的是反引号（键盘左上角 ESC 下面那个键 ），在 aardio 中反引号与双引号的作用一样 —— 都是包含原始字符串（aardio 中单引号包含的是转义字符串）。

R代码每行以分号分隔，与 aardio 一样。单行代码会直接计算并输出值，也就是说

readLines(".data.txt")

和

print( readLines(".data.txt") )

作用一样。

先简单了解几个 R 基础语法：
1、R 里的 <- 就相当于 aardio 中的等号，而 R 的等号一般只是用于键值对，其他暂时不用管。
2、R 里的 list 相当于 aardio 中的表 （table），可以包含不同类型元素，但他的键值对成员同时也是数组成员 —— 这与 aardio 的数组、字典是表的不同成分不一样。
3、R 里的向量也可以理解为 aardio 中的数组，下标自 1 开始，与 aardio 一样。

好吧，上代码：

import console;
import process.r;

//执行纯 R 代码，参数 @1 可以指定 R代码或 R 文件。
var out = process.r.exec(`
args=commandArgs(T);
write(args[1],file=".data.txt");

# list 有点像 aardio 中的表(table)，可以包含各种数据类型， 
a <- list(hello = 1, world = "字符串" ) # <- 相当于 aardio 中的等号,  R的等号一般用于分隔键值对
print ( a[["world"]] ); # aardio 里的直接下标也是这么写
print ( a$world ); # 相当于 aardio 里的  a.world
print ( a[1] ); # 这个返回的是键值对 hello = 1，不像 aadio 中 a[1] 与 a.hello 是指向不同的元素。
print ( mode(a[1]) ); # 数据类型还是显示为 list

b <- TRUE #布尔值必须全大写
print( b ) 

# 向量
a = c(10, 20, 30, 40, 50)
print( a[1] ) #起始下标为 1 ,这跟 aardio 一样
print( a[1:4] ) # 取出第 1 项到第 4 项

# 定义函数，与 aardio 语法类似
new.function <- function(a,b,c) {
   result <- a * b + c # 类似 aardio 中的 return a * b + c #
   print(result) # 指定返回值以后，还能继续执行后面的代码，不像 aardio 函数 return 后面的代码被忽略。
}

print( new.function(2,3,1) )
`,"测试一下"); //可以添加不定个数的启动参数
console.log( out );
console.pause(true);

好吧，仅仅是这样传参数进去，执行个代码，获取个输出似乎还不够，我们还想直接来回传对象，继续看下面。

首先就是要安装 R 包，R 有点像 Python，包多 …… 但是默认的 R 会安装到 C:\Program Files 目录下，而这个目录默认是没有写权限的，安装包又默认是安装到这个目录下，那么安装包就要管理权限，说实话动不动来个弹框请求权限怕是不太好。我们 aardio 追求的是一切从简，能不麻烦就尽量不要麻烦。所以这里我做了一些小的改动，默认 R 包目录设置到了 AppData 目录下，那么现在就简单了，例如安装 rjson 包：

import process.r;
process.r.require("rjson","https://mirrors.ustc.edu.cn/CRAN/");

上面的代码首先会检测 R 包是否存在，存在就直接返回路径，不存在就会安装，全自动静默安装，不会有弹框啥的。

有了万能的 JSON 就有点意思了，上代码：

import console; 
import process.r;

console.showLoading(" 正在安装 rjson 包");
process.r.require("rjson","https://mirrors.ustc.edu.cn/CRAN/");//不会重复安装

var out  = process.r.exec( `
library("rjson") # 载入 rjson 包

args <- commandArgs(T);
tab <- fromJSON(args[1], simplify=FALSE);

#不要用 print ，cat 不会加一堆不必要的东西
cat( toJSON(tab) )
`, {
  name1 = "测试一下，传对象给 R 语言";
  name2 = "这是一个 aardio 对象"
})

console.dump(out);
console.pause(true);

这时候就可以把 aardio 对象直接传给 R，aardio 会自动转换为 JSON 传过去，R 输出的 JSON —— aardio 也会自动转换为 aardio 对象。

但是在 R 代码中你必须引用 rjson 解析和生成 JSON。这里要注意，返回的 json 要用 cat 输出，cat 不会加任何东西，只会输出纯 JSON。

文章写到这里，总觉得有些美中不足。我看到 rjson 里有一个 RPC 服务端的范例，说实话我就一刚看了几句 R 语言教程的小白，看了一下不会用。不过文章写到这里，还是不甘心啊，于是又跑回去研究了一下，对这个 process.r 一通大改，又在 aardio 标准库里写了个基于管道的 JSON-RPC 客户端 process.rpc.jsonClient。终于实现了 aardio / R 语言互调函数。

然后我继续封装，把 process.rpc.jsonClient 这些调用也全封装了，直接写了个最简单的函数，process.r.startRpc()，这下就太舒服了，上代码看效果：

import console; 
import process.r;
 
var rCode = /*
testabc <- function(a,b,c) {
   result <- a * b + c # 类似 aardio 中的 return a * b + c #
   print(result) # 指定返回值以后，还能继续执行后面的代码，不像 aardio 函数 return 后面的代码被忽略。
}
*/

//启动 R 
var r = process.r.startRpc(rCode);
 
//调用 R 函数
var ret  = r.testabc(2,3,1)


//打印 R 函数返回值
if(ret[["result"]]){
  console.log("R 函数返回值",ret[["result"]])
} 


console.pause(true);

换了 N 个环境反复测试通过。

可选使用下面的代码自定义 Rscript.exe 的路径：

process.r.setScriptPath("C:\Program Files\R\R-4.2.0\bin\x64\Rscript.exe")